1.4.2. Wat is het aantal ingezette uren aan personeel in loondienst (PIL) met een zorgverlener functie en het aantal ingezette uren aan personeel niet-in-loondienst (PNIL) met een zorgverlener functie per kwalificatieniveau per Dag-, Avond- en Nacht-dienst (DAN-dienst)?

Concepten

• Arbeidsovereenkomst
• Functie in organisatie-rol
• Gewerkte periode
• ODB Kwalificatiewaarde
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft deelnemer
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer
• heeft perdurantlocatie

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• heeftEindTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: IGJ 1.4.2
2# Parameters: ?peildatum, ?vestiging
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
6PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX onz-g: <http://purl.org/ozo/onz-g#>
9PREFIX onz-org: <http://purl.org/ozo/onz-org#>
10
11SELECT
12	?kwalificatie_niveau
13    (SUM(?dag) AS ?Aantal_ingezette_uren_aan_PIL_met_een_zorgfunctie_in_de_dagdienst)
14    (SUM(?avond) AS ?Aantal_ingezette_uren_aan_PIL_met_een_zorgfunctie_in_de_avonddienst)
15    (SUM(?nacht) AS ?Aantal_ingezette_uren_aan_PIL_met_een_zorgfunctie_in_de_nachtdienst)
16{
17    # BIND("2023-09-15"^^xsd:date AS ?peildatum)
18    # BIND("000001254" AS ?vestiging)
19    
20    BIND(xsd:dateTime(?peildatum) AS ?peildatum_dt)
21    BIND(?peildatum_dt + "PT7H"^^xsd:duration AS ?peildatum_7)
22    BIND(?peildatum_dt + "PT16H"^^xsd:duration AS ?peildatum_16)
23    BIND(?peildatum_dt + "PT23H"^^xsd:duration AS ?peildatum_23)
24    
25    ?gewerkte_periode 
26        a onz-pers:GewerktePeriode ;
27        onz-g:hasBeginTimeStamp ?start_werk ;
28        onz-g:hasEndTimeStamp ?eind_werk ;
29        onz-g:hasParticipant ?werknemer ;
30        onz-g:hasPerdurantLocation ?werk_locatie ;
31        onz-g:hasQuality / onz-g:hasQualityValue / onz-g:hasDataValue ?gewerkte_uren ;
32        onz-g:definedBy ?overeenkomst .
33
34    FILTER(?peildatum = xsd:date(?start_werk))
35
36    ?overeenkomst 
37        a onz-pers:ArbeidsOvereenkomst ;
38        onz-pers:heeftOpdrachtnemer ?medewerker ;
39        onz-g:hasPart ?overeenkomst_afspraak .
40    ?overeenkomst_afspraak
41        a onz-pers:WerkOvereenkomstAfspraak ;
42        onz-g:startDatum ?start_afspraak .
43    OPTIONAL {
44    ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
45    }
46    FILTER (?start_afspraak <= ?peildatum && (?eind_afspraak >= ?peildatum || !BOUND(?eind_afspraak)))
47    
48    # Bepaald het vestigingsnummer dat hoort bij de werkafspraak
49    ?overeenkomst_afspraak onz-g:isAbout ?locatie .
50    ?locatie 
51        a onz-g:StationaryArtifact ;
52        onz-g:partOf* ?vestiging_uri .
53    ?vestiging_uri 
54        a onz-org:Vestiging ;
55            onz-g:identifiedBy ?vestigingsnummer_object .
56    ?vestigingsnummer_object
57        a onz-org:Vestigingsnummer ;
58        onz-g:hasDataValue ?vestigingsnummer .
59    
60    # Bepaal het niveau van de functie
61    ?overeenkomst_afspraak onz-g:isAbout ?functie .
62    ?functie
63        a onz-g:OccupationalPositionRole ;
64        onz-g:hasQuality/onz-g:hasQualityValue ?kwalificatie .
65    ?kwalificatie a onz-pers:ODBKwalificatieWaarde .
66    { 
67        BIND("Totaal" AS ?kwalificatie_niveau)
68    } UNION {
69        ?kwalificatie rdfs:label ?kwalificatie_niveau
70    }
71    BIND(IF(?start_werk >= ?peildatum_7 && ?start_werk < ?peildatum_16, ?gewerkte_uren, 0) AS ?dag)
72    BIND(IF(?start_werk >= ?peildatum_16 && ?start_werk < ?peildatum_23, ?gewerkte_uren, 0) AS ?avond)
73    BIND(IF(?dag || ?avond, 0, ?gewerkte_uren) AS ?nacht)
74}
75GROUP BY ?kwalificatie_niveau
76ORDER BY ?kwalificatie_niveau